Listado de Altas de Fichas

FORMULARIO

INFORME

CÓDIGO

Programa "ver_actas_fichas.prg"

  *---------------------------------------------------------------------------------------------------------
  *--PARAMETROS DEL PROGRAMA--------------------------------------------------------------------------------
  PARAMETERS ficha,tipo,mesVigente,anioVigente
  *---------------------------------------------------------------------------------------------------------
  *--RUTINA DE INICIACION-----------------------------------------------------------------------------------
  *---------------------------------------------------------------------------------------------------------
  CLEAR
  CLOSE TABLES all
  SET CENTURY ON
  SET DATE TO french
  *---------------------------------------------------------------------------------------------------------
  *--LLAMO AL CARTEL DE ESPERA------------------------------------------------------------------------------
  *---------------------------------------------------------------------------------------------------------
  procesando=vm_formularios+"frmprocesando.scx"
  DO FORM &procesando
  *---------------------------------------------------------------------------------------------------------
  *--TRAIGO LOS DATOS DE LAS TABLAS DH01,DH03 y DH25--------------------------------------------------------
  *---------------------------------------------------------------------------------------------------------
  **Tabla DH01**
  consulta01="select nro_legaj,desc_appat,desc_nombr";
  		+" from dh01";
  		
  nom01=SYS(3)
  CREATE SQL VIEW &nom01;
  CONNECTION con_pampasql;
  AS &consulta01
  SELE SELE(1)
  USE &nom01 ALIAS v01
  *Creo Tabla
  tabla01=vm_bases_informes+"dh01Activos"
  *Creo Consulta
  SELECT *;
  FROM v01;
  ORDER BY v01.nro_legaj;
  INTO TABLE &tabla01
  *Destruyo Vista
  SELECT v01
  USE 
  DROP VIEW &nom01
  
  *SELECT dh01Activos
  *BROWSE
  *---------------------------------------------------------------------------------------------------------
  **Tabla DH03**
  consulta03="select distinct nro_legaj,nro_cargo,codc_uacad";
  		+" from dh03";
  	
  nom03=SYS(3)
  CREATE SQL VIEW &nom03;
  CONNECTION con_pampasql;
  AS &consulta03
  SELE SELE(1)
  USE &nom03 ALIAS v03
  *Creo Tabla
  tabla03=vm_bases_informes+"dh03Activos"
  *Creo Consulta
  SELECT *;
  FROM v03;
  ORDER BY v03.nro_legaj;
  INTO TABLE &tabla03
  *Destruyo Vista
  SELECT v03
  USE 
  DROP VIEW &nom03
  
  *SELECT dh03Activos
  *BROWSE
  *---------------------------------------------------------------------------------------------------------
  **Tabla DH25**
  
  consulta25="select nro_cargo,nro_liqui,codn_conce,tipo_noved,detallenovedad,nro_nove1,vig_nomes,vig_noano";
  		+" from dh25"
  
  nom25=SYS(3)
  CREATE SQL VIEW &nom25;
  CONNECTION con_pampasql;
  AS &consulta25
  SELECT SELECT (1)
  USE &nom25 ALIAS v25
  *Creo Tabla
  tabla25=vm_bases_informes+"dh25Activos"
  *Creo Consulta
  SELECT *;
  FROM v25;
  ORDER BY v25.nro_cargo;
  INTO TABLE &tabla25
  *Destruyo Vista
  SELECT v25
  USE 
  DROP VIEW &nom25
  
  *SELECT dh25Activos
  *BROWSE
  *---------------------------------------------------------------------------------------------------------
  *---------------------------------------------------------------------------------------------------------
  *--CREO LA TABLA FINAL----------------------------------------------------------------------------------
  *---------------------------------------------------------------------------------------------------------
  tablaFinal=vm_bases_informes+"actasFichas"
  
  SELECT *;
  FROM dh01Activos INNER JOIN(dh03Activos INNER JOIN dh25Activos;
  ON dh03Activos.nro_cargo=dh25Activos.nro_cargo);
  ON dh01Activos.nro_legaj=dh03Activos.nro_legaj; 
  WHERE dh25Activos.codn_conce=VAL(ficha) AND dh25Activos.tipo_noved=ALLTRIM(tipo) AND;
  dh25Activos.vig_nomes=VAL(mesVigente) AND dh25Activos.vig_noano=VAL(anioVigente);
  ORDER BY dh03Activos.codc_uacad;
  INTO TABLE &tablaFinal
  *---------------------------------------------------------------------------------------------------------
  *--CIERRO EL CARTEL DE ESPERA------------------------------------------------------------------------------
  *---------------------------------------------------------------------------------------------------------
  frmprocesando.release
  *---------------------------------------------------------------------------------------------------------
  *--MUESTRO LA TABLA GENERAL-------------------------------------------------------------------------------
  *---------------------------------------------------------------------------------------------------------
  *SELECT actasFichas
  *BROWSE
  *---------------------------------------------------------------------------------------------------------
  *--MUESTRO EL REPORTE FINAL-------------------------------------------------------------------------------
  *---------------------------------------------------------------------------------------------------------
  IF(RECCOUNT("actasFichas")==0)
  	MESSAGEBOX("Su consulta no genero resultados")
  ELSE
  	informe=vm_informes+"frx_actas_fichas.frx"
  	report form &informe preview
  ENDIF

Botón "Procesar" (btnProcesar)

  *---------------------------------------------------------------------------------------------------------
  *--CAPTURO LOS VALORES DE LOS COMBO QUE SERAN PASADO AL PROGRAMA COMO PARAMETRO---------------------------
  *---------------------------------------------------------------------------------------------------------
  ficha=THISFORM.cmbFicha.value
  tipo=THISFORM.cmbTipo.value
  mesVigencia=THISFORM.cmbMes.value
  anioVigencia=THISFORM.cmbAnio.value
  *---------------------------------------------------------------------------------------------------------
  *--LLAMO AL PROGRAMA--------------------------------------------------------------------------------------
  *---------------------------------------------------------------------------------------------------------
  IF(ISNULL(ficha)=.T. OR ISNULL(tipo)=.T. OR ISNULL(mesVigencia)=.T. OR ISNULL(anioVigencia)=.T.)
  	MESSAGEBOX("Faltan completar datos del formulario")
  ELSE 
  	programa=vm_programas + "ver_actas_fichas.prg"
  	DO &programa WITH ficha,tipo,mesVigencia,anioVigencia
  ENDIF

Botón "Cancelar" (btnCancelar)

  THISFORM.Release

Botón "Ayuda"(btnAyuda)

  DECLARE INTEGER ShellExecute ;
  IN SHELL32.DLL ;
  INTEGER nWinHandle,; 
  STRING cOperation,;
  STRING cFileName,;
  STRING cParameters,;
  STRING cDirectory,;
  INTEGER nShowWindow
  
  V_busca='R:\werken\docs\List_Actas_Fichas.pdf'
  ShellExecute(0,"open",V_busca,"", Fullpath(""),0)